🖥️✨ Microsoft Excel এ নাম্বারকে Word এ কনভার্ট করার নিয়ম 📋⌨️

Microsoft Excel আমাদের দৈনন্দিন অফিস কাজের অন্যতম অপরিহার্য একটি সফটওয়্যার। এখানে আমরা সাধারণত হিসাব-নিকাশ, ডেটা ম্যানেজমেন্ট বা টেবিল তৈরির জন্য সংখ্যা ব্যবহার করি। কিন্তু অনেক ক্ষেত্রে শুধুমাত্র সংখ্যাই যথেষ্ট নয় সেই সংখ্যাকে শব্দে রূপান্তর করতে হয়। যেমনঃ একটি ইনভয়েস বা বিল তৈরি করার সময় মোট টাকা সংখ্যার পাশাপাশি শব্দেও লেখা জরুরি হয়ে পড়ে। হাতে লিখে শব্দে রূপান্তর করা সময়সাপেক্ষ এবং ভুল হওয়ার সম্ভাবনাও থেকে যায়।

এই সমস্যার সহজ সমাধান হলো Excel-এ সংখ্যা থেকে শব্দে রূপান্তরের নিয়ম ব্যবহার করা। যদিও Excel-এ এর জন্য সরাসরি কোনো বিল্ট-ইন ফাংশন নেই, তবে VBA (Visual Basic for Applications) কোড ব্যবহার করে খুব সহজেই এই কাজটি করা যায়। এর মাধ্যমে আপনার সময় বাঁচবে, নির্ভুলভাবে কাজ হবে এবং পেশাদার মানের ডকুমেন্ট তৈরি করা সম্ভব হবে।

🖥️✨ Microsoft Excel এ নাম্বারকে Word এ কনভার্ট করার নিয়ম 📋⌨️

প্রথমে আমরা কিছু সংখ্যা লিখে নিয়েছি। 

এই টেবিল ব্যবহার করেই আমরা দেখাব। আরেকটি কথা Microsoft Office এর Old Version এ SpellNumber ফাংশন আলাদা করে দেও ছিল। কিন্তু নতুন Version এ নাই। তাই আমাদের Developer Tab চালু করে VBA কোড ব্যবহার করতে হবে। এর জন্য Developer Tab চালু করতে হবে। চলুন দেখি Developer Tab কিভাবে চালু করতে হয়। 

✅ Developer Tab চালু করবেন কিভাবে... ❓

Excel-এ VBA কোড ব্যবহার করতে হলে আগে Developer Tab চালু করতে হবে।

প্রথমে File এ ক্লিক করব।

তারপর Options এ ক্লিক করব। 

তারপর Customize Ribbon এ ক্লিক করব।

তারপর এখানে Developer এ টিক চিহ্ন দিয়ে দাও। 

তারপর ওকে করুন।

এখন দেখেন Developer Tab চালু হয়ে গেছে। 

Developer Tab চালু করার কাজ শেষ।

✅ VBA কোড লেখা 📝

এখন আমরা একটি কোড ব্যবহার করব যা সংখ্যাকে ইংরেজি শব্দে কনভার্ট করবে।

প্রথমে Developer Tab এ ক্লিক করুন। 

তারপর Visual Basic এ ক্লিক করুন।

তারপর Insert এ ক্লিক করুন। 

তারপর Module এ ক্লিক করুন।

তারপর নিচের কোডটি কপি করে পেস্ট করুন:

Function SpellNumber(ByVal MyNumber)
    Dim Units As Variant, Tens As Variant
    Dim Temp As String, DecimalPlace As Integer
    Dim Count As Integer
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    
    ' Convert MyNumber to string and trim extra spaces
    MyNumber = Trim(Str(MyNumber))
    
    ' Find decimal place.
    DecimalPlace = InStr(MyNumber, ".")
    If DecimalPlace > 0 Then
        MyNumber = Left(MyNumber, DecimalPlace - 1)
    End If
    
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then SpellNumber = Temp & Place(Count) & SpellNumber
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    SpellNumber = Application.Trim(SpellNumber)
End Function
Private Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function
Private Function GetTens(TensText)
    Dim Result As String
    If Val(Left(TensText, 1)) = 1 Then
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit(Right(TensText, 1))
    End If
    GetTens = Result
End Function
Private Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function
  

তারপর Keyboard এর Ctrl+S চাপ দিন।তারপর এরকম আসবে। এখানে Save এ ক্লিক করুন। 

তারপর এগুলো কেটে দিয়ে Home এ চলে আসেন। 

এখানের কাজ শেষ।

✅ Excel এ নাম্বারকে Word এ কনভার্ট করব 📝

এর জন্য আমাদের B2 সেলে ক্লিক করব। তারপর = চিহ্ন দিব।

তারপর এখানে SpellNumber লিখব আর ফাস্ট ব্যাকেট দিব।

তারপর A2 সেলে ক্লিক করব। তারপর ফাস্ট ব্যাকেট ক্লোজ করব।

তারপর Keyboard এর Enter বাটন চাপ দিব। তাহলে রেজাল্ট চলে আসবে।

রেজাল্ট চলে এসেছে। বাকি গুলো আনার জন্য ড্রাগ করে নিয়ে টেনে নামাবো।

তারপর দেখেন বাকি গুলোও চলে এসেছে। 

আশা করি বুঝতে পেরেছেন।

✅ বাড়তি টিপস 📝

• যদি আপনি বাংলায় সংখ্যা থেকে শব্দ করতে চান, তাহলে VBA কোড কিছুটা পরিবর্তন করতে হবে। আপনারা যদি বাংলা VBA কোড নিয়ে পোস্ট চান তাহলে কমেন্ট করে জানান। 
• এভাবে Salary Sheet, Invoice, Bill, বা Bank Statement-এ সংখ্যা থেকে শব্দ রূপান্তর করা খুব কাজে লাগে।

✅ আমার শেষ কথা 📝

সংখ্যাকে শব্দে রূপান্তর করার মাধ্যমে Excel-এর ব্যবহার আরও বহুমুখী হয়ে ওঠে। রিপোর্ট, ইনভয়েস, বিল, বেতন স্লিপ বা ব্যাংক স্টেটমেন্টে স্বয়ংক্রিয়ভাবে সংখ্যার শব্দ তৈরি হলে কাজের গতি যেমন বেড়ে যায়, তেমনি ভুলের সম্ভাবনাও কমে যায়। এর ফলে Excel শুধু ডেটা বিশ্লেষণ নয়, বরং প্রফেশনাল ডকুমেন্ট তৈরির ক্ষেত্রেও আরও কার্যকর হয়ে ওঠে।

সবচেয়ে বড় সুবিধা হলো একবার VBA কোড সেটআপ করে নিলে ভবিষ্যতে আর আলাদা করে লিখতে হয় না। শুধু একটি ফর্মুলা ব্যবহার করলেই যেকোনো সংখ্যা মুহূর্তেই শব্দে রূপান্তরিত হবে। তাই যারা নিয়মিত Excel ব্যবহার করেন, তাদের জন্য এই কৌশল জানা অত্যন্ত গুরুত্বপূর্ণ। এটি কাজকে সহজ, দ্রুত এবং নির্ভুল করে তোলে।